Home / Indice sezione

www.icosaedro.it

 PHP EBNF Syntax

Il manuale ufficiale del PHP descrive il linguaggio attraverso alcuni esempi concreti. Questo facilita l'apprendimento dei rudimenti, ma poi sorgono dei dubbi sulla esatta sintassi di certi elementi. Quello che manca alla documentazione ufficiale è una guida di riferimento che descrive la sintassi del linguaggio in modo rigoroso. Questo articolo tenta di colmare questa lacuna e presenta la sintassi EBNF del linguaggio PHP versione 5.2.0.

Indice

Cos'è l'EBNF
Come il PHP analizza ed esegue il programma
La sintassi EBNF del PHP
Riferimenti
Argomenti correlati

Cos'è l'EBNF

L'EBNF (Extended Backus-Naur Form) è un modo conciso e rigoroso per esprimere la sintassi di un linguaggio di programmazione. L'EBNF fu proposto da Niklaus Wirth (1977) come estensione del formalismo BNF utilizzato per la definizione del linguaggio Algol 60.

La sintassi EBNF descrive nel dettaglio l'ordine dei simboli e delle parole ammessi dal linguaggio. Ad esempio, un numero intero costituito da una sequenza di una o più cifre potrebbe essere definito così:

intero = cifra { cifra } ;
cifra = "0" .. "9" ;

La parola intero è il nome che abbiamo dato a questa entità del linguaggio; questa entità viene definita da una regola che dice che il numero intero è formato da una cifra alla quale seguono zero o più altre cifre. Le parentesi graffe indicano che l'espressione al loro interno può essere ripetuta zero o più volte. La seconda regola definisce l'entità cifra come intervallo dei caratteri che vanno dallo zero al nove. Le stringhe incluse tra doppi apici sono costanti letterali, cioè i caratteri del testo che devono corrispondere.

A volte ci sono delle parti opzionali della sintassi, cioè delle sotto-espressioni la cui presenza è opzionale. Per indicare questo fatto la sotto-espressione deve essere racchiusa tra parentesi quadrate. Le alternative si esprimono con l'operatore | (barra verticale). Ad esempio, la seguente sintassi descrive i numeri a virgola mobile:

virgola_mobile = intero (decimali | esponente | decimali esponente);
segno = "+" | "-";
decimali = "." intero ;
esponente = "E" [segno] intero ;

Queste regole dicono che un numero in virgola mobile deve avere una parte intera seguita da una parte decimale oppure dall'esponente o da entrambi; in altri termini, se non è presente almeno il punto decimale oppure l'esponente, allora la sintassi non è corretta. Le parentesi tonde sono necessarie perché l'operatore "|" ha precedenza minore rispetto alla semplice sequenza di fattori. Notare che il segno dell'esponente è opzionale.

Il formalismo EBNF si può applicare per descrivere le regole che governano una successione di simboli qualsiasi, non solo singoli caratteri. A questo livello di astrazione gli elementi del linguaggio la cui sintassi viene descritta sono degli identificatori non definiti dalla sintassi stessa. Nelle applicazioni ai compilatori e ai validatori, in generale si costruisce prima uno scanner che trasforma la successione dei caratteri in simboli, e poi si costruisce il parser che analizza la successione dei simboli prodotti dallo scanner. La sintassi EBNF viene impiegata per descrivere la sintassi a livello di scanner o la sintassi a livello di parser, o entrambe le cose.

Come il PHP analizza ed esegue il programma

Come abbiamo accennato, i programmi che analizzano i sorgenti dei linguaggi di programmazione in generale sono organizzati in almeno due stadi: lo scanner e il parser. Lo scanner analizza il testo sorgente e converte la sequenza dei caratteri in simboli (detti anche token), cioè in codici che rappresentano i vari elementi del linguaggio. La pagina http://it.php.net/manual/en/tokens.php elenca i token prodotti dallo scanner dell'interprete PHP. Alcuni token rappresentano le parole riservate del linguaggio, come include if else switch echo ... Altri token rappresentano gli operatori, come + - * / ++ -- ... Altri token ancora rappresentano parti variabili del linguaggio come i numeri o i nomi delle funzioni e delle variabili.

Una volta scomposto il testo sorgente in una sequenza di token, il lavoro del parser risulta notevolmente semplificato. Lo scopo del parser è controllare la corretta successione dei simboli secondo la sintassi EBNF che presentiamo in questo articolo. In generale gli errori rilevati in questa fase sono fatali, cioè causano l'interruzione della esecuzione.

L'analisi svolta dal parser è indispensabile per guidare la fase successiva dell'interprete, cioè il compilatore. Il compilatore produce uno pseudo-codice che può essere eseguito direttamente dall'interprete dello pseudo-codice. Finalmente il nostro programma sta girando!

La sintassi EBNF del PHP

Il pacchetto sorgente del PHP include il file Zend/zend_language_parser.y che contiene la sintassi BNF usata dall'analizzatore Yacc. Il BNF è piuttosto involuto ed è difficile da leggere. Ecco perché l'ho tradotto in EBNF e formattato per benino. Si tratta della sintassi relativa al PHP 5.2.0. Perché solo il PHP 5 e non il PHP 4 che è ancora così diffuso? Io penso che i principali fruitori di questo documento saranno coloro che affrontano il linguaggio PHP per la prima volta, e quindi meglio cominciare con la versione più recente disponibile.

Il file zend_language_parser.y da cui ho ricavato la sintassi EBNF si trova nel pacchetto sorgente del PHP, ed è disponibile anche in questo file:

php-syntax-yacc.txt

La sintassi EBNF da me prodotta si trova in questo file in formato testo:

php-syntax-ebnf.txt

Da questo testo ho ricavato la forma HTML che riporto qui sotto usando il programma BNF_CHK (http://www.icosaedro.it/bnf_chk/). Questo programma numera le regole e mette degli indici ai simboli in modo da trovare rapidamente la regola che lo definisce. Alcuni simboli il cui nome inizia con T_* sono individuati dallo scanner del PHP e non sono ulteriormente descritti in questa sintassi; vanno perciò considerati come simboli primitivi.

IDs report:

PHP_SOURCE_TEXT: defined in line 14, NOT USED

T_INLINE_HTML: NOT DEFINED, used 1 times

T_ENCAPSED_AND_WHITESPACE: NOT DEFINED, used 1 times

T_CHARACTER: NOT DEFINED, used 1 times

1. PHP_SOURCE_TEXT = { inner_statement₃ | halt_compiler_statement₂ } ;

2. halt_compiler_statement = "__halt_compiler" "(" ")" ";" ;

3. inner_statement = statement₅ | function_declaration_statement₈ | class_declaration_statement₉ ;

4. inner_statement_list = { inner_statement₃ } ;

5. statement = "{" inner_statement_list₄ "}" | "if" "(" expr₅₄ ")" statement₅ { elseif_branch₂₃ } [ else_single₂₅ ] | "if" "(" expr₅₄ ")" ":" inner_statement_list₄ { new_elseif_branch₂₄ } [ new_else_single₂₆ ] "endif" ";" | "while" "(" expr₅₄ ")" while_statement₂₂ | "do" statement₅ "while" "(" expr₅₄ ")" ";" | "for" "(" for_expr₄₀ ";" for_expr₄₀ ";" for_expr₄₀ ")" for_statement₁₆ | "switch" "(" expr₅₄ ")" switch_case_list₂₀ | "break" [ expr₅₄ ] ";" | "continue" [ expr₅₄ ] ";" | "return" [ expr_without_variable₄₁ | variable₅₈ ] ";" | "global" global_var₃₁ { "," global_var₃₁ } ";" | "static" static_var₃₂ { "," static_var₃₂ } ";" | "echo" echo_expr_list₃₉ ";" | T_INLINE_HTML_? | expr₅₄ ";" | "use" use_filename₇ ";" | "unset" "(" variable₅₈ { "," variable₅₈ } ")" ";" | "foreach" "(" ( variable₅₈ | expr_without_variable₄₁ ) "as" foreach_variable₁₅ [ "=>" foreach_variable₁₅ ] ")" foreach_statement₁₇ | "declare" "(" declare_list₁₉ ")" declare_statement₁₈ | ";" | "try" "{" inner_statement_list₄ "}" catch_branch₆ { catch_branch₆ } | "throw" expr₅₄ ";" ;

6. catch_branch = "catch" "(" fully_qualified_class_name₄₃ T_VARIABLE₈₂ ")" "{" inner_statement_list₄ "}" ;

7. use_filename = T_CONSTANT_ENCAPSED_STRING₉₅ | "(" T_CONSTANT_ENCAPSED_STRING₉₅ ")" ;

8. function_declaration_statement = "function" [ "&" ] T_STRING₈₀ "(" parameter_list₂₇ ")" "{" inner_statement_list₄ "}" ;

9. class_declaration_statement = class_entry_type₁₀ T_STRING₈₀ [ extends_from₁₁ ] [ implements_list₁₃ ] "{" { class_statement₃₃ } "}" | "interface" T_STRING₈₀ [ interface_extends_list₁₂ ] "{" { class_statement₃₃ } "}" ;

10. class_entry_type = [ "abstract" | "final" ] "class" ;

11. extends_from = "extends" fully_qualified_class_name₄₃ ;

12. interface_extends_list = "extends" interface_list₁₄ ;

13. implements_list = "implements" interface_list₁₄ ;

14. interface_list = fully_qualified_class_name₄₃ { "," fully_qualified_class_name₄₃ } ;

15. foreach_variable = [ "&" ] variable₅₈ ;

16. for_statement = statement₅ | ":" inner_statement_list₄ "endfor" ";" ;

17. foreach_statement = statement₅ | ":" inner_statement_list₄ "endforeach" ";" ;

18. declare_statement = statement₅ | ":" inner_statement_list₄ "enddeclare" ";" ;

19. declare_list = T_STRING₈₀ "=" static_scalar₄₉ { "," T_STRING₈₀ "=" static_scalar₄₉ } ;

20. switch_case_list = "{" [ ";" ] { case_list₂₁ } "}" | ":" [ ";" ] { case_list₂₁ } "endswitch" ";" ;

21. case_list = "case" expr₅₄ [ ":" | ";" ] inner_statement_list₄ | "default" [ ":" | ";" ] inner_statement_list₄ ;

22. while_statement = statement₅ | ":" inner_statement_list₄ "endwhile" ";" ;

23. elseif_branch = "elseif" "(" expr₅₄ ")" statement₅ ;

24. new_elseif_branch = "elseif" "(" expr₅₄ ")" ":" inner_statement_list₄ ;

25. else_single = "else" statement₅ ;

26. new_else_single = "else" ":" inner_statement_list₄ ;

27. parameter_list = [ parameter₂₈ { "," parameter₂₈ } ] ;

28. parameter = [ T_STRING₈₀ | "array" ] [ "&" ] T_VARIABLE₈₂ [ "=" static_scalar₄₉ ] ;

29. function_call_parameter_list = [ function_call_parameter₃₀ { "," function_call_parameter₃₀ } ] ;

30. function_call_parameter = expr_without_variable₄₁ | variable₅₈ | "&" w_variable₅₆ ;

31. global_var = T_VARIABLE₈₂ | "$" r_variable₅₅ | "$" "{" expr₅₄ "}" ;

32. static_var = T_VARIABLE₈₂ [ "=" static_scalar₄₉ ] ;

33. class_statement = variable_modifiers₃₅ class_variable_declaration₃₇ { "," class_variable_declaration₃₇ } ";" | "const" class_constant_declaration₃₈ { "," class_constant_declaration₃₈ } ";" | { modifier₃₆ } "function" [ "&" ] T_STRING₈₀ "(" parameter_list₂₇ ")" method_body₃₄ ;

34. method_body = ";" | "{" inner_statement_list₄ "}" ;

35. variable_modifiers = "var" | modifier₃₆ { modifier₃₆ } ;

36. modifier = "public" | "protected" | "private" | "static" | "abstract" | "final" ;

37. class_variable_declaration = ( "var" | modifier₃₆ { modifier₃₆ } ) T_VARIABLE₈₂ [ "=" static_scalar₄₉ ] ;

38. class_constant_declaration = T_STRING₈₀ "=" static_scalar₄₉ ;

39. echo_expr_list = expr₅₄ { "," expr₅₄ } ;

40. for_expr = [ expr₅₄ { "," expr₅₄ } ] ;

41. expr_without_variable = "list" "(" assignment_list₇₀ ")" "=" expr₅₄ | variable₅₈ "=" expr₅₄ | variable₅₈ "=" "&" variable₅₈ | variable₅₈ "=" "&" "new" class_name_reference₄₄ [ ctor_arguments₄₇ ] | "new" class_name_reference₄₄ [ ctor_arguments₄₇ ] | "clone" expr₅₄ | variable₅₈ ( "+=" | "-=" | "*=" | "/=" | ".=" | "%=" | "&=" | "|=" | "^=" | "<<=" | ">>=" ) expr₅₄ | rw_variable₅₇ "++" | "++" rw_variable₅₇ | rw_variable₅₇ "--" | "--" rw_variable₅₇ | expr₅₄ ( "||" | "&&" | "or" | "and" | "xor" | "|" | "&" | "^" | "." | "+" | "-" | "*" | "/" | "%" | "<<" | ">>" | "===" | "!==" | "<" | "<=" | ">" | ">=" ) expr₅₄ | ( "+" | "-" | "!" | "~" ) expr₅₄ | expr₅₄ "instanceof" class_name_reference₄₄ | "(" expr₅₄ ")" | expr₅₄ "?" expr₅₄ ":" expr₅₄ | internal_functions₇₇ | "(int)" expr₅₄ | "(double)" expr₅₄ | "(float)" expr₅₄ | "(real)" expr₅₄ | "(string)" expr₅₄ | "(array)" expr₅₄ | "(object)" expr₅₄ | "(bool)" expr₅₄ | "(boolean)" expr₅₄ | "(unset)" expr₅₄ | "exit" [ exit_expr₄₆ ] | "die" [ exit_expr₄₆ ] | "@" expr₅₄ | scalar₅₁ | "array" "(" [ array_pair_list₇₂ ] ")" | "`" encaps_list₇₄ "`" | "print" expr₅₄ ;

42. function_call = T_STRING₈₀ "(" function_call_parameter_list₂₉ ")" | fully_qualified_class_name₄₃ "::" T_STRING₈₀ "(" function_call_parameter_list₂₉ ")" | fully_qualified_class_name₄₃ "::" variable_without_objects₆₀ "(" function_call_parameter_list₂₉ ")" | variable_without_objects₆₀ "(" function_call_parameter_list₂₉ ")" ;

43. fully_qualified_class_name = T_STRING₈₀ ;

44. class_name_reference = T_STRING₈₀ | dynamic_class_name_reference₄₅ ;

45. dynamic_class_name_reference = base_variable₆₃ "->" object_property₆₇ { "->" object_property₆₇ } | base_variable₆₃ ;

46. exit_expr = "(" [ expr₅₄ ] ")" ;

47. ctor_arguments = "(" function_call_parameter_list₂₉ ")" ;

48. common_scalar = T_LNUMBER₈₃ | T_DNUMBER₉₀ | T_CONSTANT_ENCAPSED_STRING₉₅ | "__LINE__" | "__FILE__" | "__CLASS__" | "__METHOD__" | "__FUNCTION__" ;

49. static_scalar = common_scalar₄₈ | T_STRING₈₀ | "+" static_scalar₄₉ | "-" static_scalar₄₉ | "array" "(" [ static_array_pair_list₅₂ ] ")" | static_class_constant₅₀ ;

50. static_class_constant = T_STRING₈₀ "::" T_STRING₈₀ ;

51. scalar = T_STRING₈₀ | T_STRING_VARNAME₉₈ | class_constant₇₈ | common_scalar₄₈ | "\"" encaps_list₇₄ "\"" | "'" encaps_list₇₄ "'" | T_START_HEREDOC₁₀₀ encaps_list₇₄ T_END_HEREDOC₁₀₂ ;

52. static_array_pair_list = static_array_pair₅₃ { "," static_array_pair₅₃ } [ "," ] ;

53. static_array_pair = static_scalar₄₉ [ "=>" static_scalar₄₉ ] ;

54. expr = r_variable₅₅ | expr_without_variable₄₁ ;

55. r_variable = variable₅₈ ;

56. w_variable = variable₅₈ ;

57. rw_variable = variable₅₈ ;

58. variable = base_variable_with_function_calls₆₂ [ "->" object_property₆₇ method_parameters₅₉ { "->" object_property₆₇ method_parameters₅₉ } ] ;

59. method_parameters = "(" function_call_parameter_list₂₉ ")" ;

60. variable_without_objects = reference_variable₆₄ | simple_indirect_reference₆₉ reference_variable₆₄ ;

61. static_member = fully_qualified_class_name₄₃ "::" variable_without_objects₆₀ ;

62. base_variable_with_function_calls = base_variable₆₃ | function_call₄₂ ;

63. base_variable = reference_variable₆₄ | simple_indirect_reference₆₉ reference_variable₆₄ | static_member₆₁ ;

64. reference_variable = compound_variable₆₅ { selector₆₆ } ;

65. compound_variable = T_VARIABLE₈₂ | "$" "{" expr₅₄ "}" ;

66. selector = "[" [ expr₅₄ ] "]" | "{" expr₅₄ "}" ;

67. object_property = variable_name₆₈ { selector₆₆ } | variable_without_objects₆₀ ;

68. variable_name = T_STRING₈₀ | "{" expr₅₄ "}" ;

69. simple_indirect_reference = "$" { "$" } ;

70. assignment_list = [ assignment_list_element₇₁ ] { "," [ assignment_list_element₇₁ ] } ;

71. assignment_list_element = variable₅₈ | "list" "(" assignment_list₇₀ ")" ;

72. array_pair_list = array_pair₇₃ { "," array_pair₇₃ } [ "," ] ;

73. array_pair = "&" w_variable₅₆ | expr₅₄ "=>" "&" w_variable₅₆ | expr₅₄ "=>" expr₅₄ ;

74. encaps_list = { encaps_var₇₅ | T_STRING₈₀ | T_NUM_STRING₉₉ | T_ENCAPSED_AND_WHITESPACE_? | T_CHARACTER_? | T_BAD_CHARACTER₈₁ | "[" | "]" | "{" | "}" | "->" } ;

75. encaps_var = T_VARIABLE₈₂ [ "[" encaps_var_offset₇₆ "]" ] | T_VARIABLE₈₂ "->" T_STRING₈₀ | "${" expr₅₄ "}" | "${" T_STRING_VARNAME₉₈ "[" expr₅₄ "]" "}" | T_CURLY_OPEN₉₄ variable₅₈ "}" ;

76. encaps_var_offset = T_STRING₈₀ | T_NUM_STRING₉₉ | T_VARIABLE₈₂ ;

77. internal_functions = "isset" "(" variable₅₈ { "," variable₅₈ } ")" | "empty" "(" variable₅₈ ")" | "include" expr₅₄ | "include_once" expr₅₄ | "eval" "(" expr₅₄ ")" | "require" expr₅₄ | "require_once" expr₅₄ ;

78. class_constant = fully_qualified_class_name₄₃ "::" T_STRING₈₀ ;

79. LABEL = ( letter₈₉ | "_" ) { letter₈₉ | digit₈₇ | "_" } ;

80. T_STRING = LABEL₇₉ ;

81. T_BAD_CHARACTER = "\x00".."\x08" | "\x0b" | "\x0c" | "\x0e".."\x1f" ;

82. T_VARIABLE = "$" T_STRING₈₀ ;

83. T_LNUMBER = octal₈₄ | decimal₈₅ | hexadecinal₈₆ ;

84. octal = "0" { "0".."7" } ;

85. decimal = "1".."9" { digit₈₇ } ;

86. hexadecinal = "0x" hexdigit₈₈ { hexdigit₈₈ } ;

87. digit = "0".."9" ;

88. hexdigit = digit₈₇ | "a".."f" | "A".."F" ;

89. letter = "a".."z" | "A".."Z" | "\x7f".."\xff" ;

90. T_DNUMBER = DNUM₉₁ | EXPONENT_DNUM₉₂ ;

91. DNUM = digit₈₇ [ "." ] digit₈₇ { digit₈₇ } | digit₈₇ { digit₈₇ } [ "." ] { digit₈₇ } ;

92. EXPONENT_DNUM = ( LNUM₉₃ | DNUM₉₁ ) ( "e" | "E" ) [ "+" | "-" ] LNUM₉₃ ;

93. LNUM = digit₈₇ { digit₈₇ } ;

94. T_CURLY_OPEN = "${" ;

95. T_CONSTANT_ENCAPSED_STRING = single_quoted_constant_string₉₆ | double_quoted_constant_string₉₇ ;

96. single_quoted_constant_string = "'" { "any char except ' and \\" | "\\" "any char" } "'" ;

97. double_quoted_constant_string = "\"" { "any char except $ \" and \\" | "\\" "any char" } "\"" ;

98. T_STRING_VARNAME = LABEL₇₉ ;

99. T_NUM_STRING = LNUM₉₃ | hexadecinal₈₆ ;

100. T_START_HEREDOC = "<<<" { " " | "\t" } LABEL₇₉ NEWLINE₁₀₁ ;

101. NEWLINE = "\r" | "\n" | "\r\n" ;

102. T_END_HEREDOC = "FIXME: here at the beginning of the line" LABEL₇₉ [ ";" ] NEWLINE₁₀₁ ;

Da ricordare: sono case-insensitive le parole riservate del linguaggio e i nomi di funzione, classi e metodi. Tutti gli altri identificatori sono case-sensitive.

Riferimenti

• BNF Syntax Checker (http://www.icosaedro.it/bnf_chk/index.html). Programma per la verifica e la formattazione di una sintassi EBNF.
• www.php.net. Il sito ufficiale del PHP. Da qui si scarica il sorgente completo del linguaggio, dal quale ho tratto la sintassi EBNF.
• BNF and EBNF: What are they and how do they work? (www.garshol.priv.no/download/text/bnf.html) di Lars Marius Garshol (2003). Articolo che spiega e confronta il BNF e l'EBNF e la loro applicazione per definire la sintassi dei linguaggi di programmazione e per costruire i relativi compilatori.

Argomenti correlati

• PHP Analisi Critica. Disamina del PHP come linguaggio, con particolare riferimento alla sintassi e ai possibili miglioramenti.
• Esercizi di PHP. Una raccolta di articoli dedicati al PHP, con temi di approfondimento e con problemi concreti risolti.
• PHPLint. Validatore sintattico e semantico per programmi PHP. Implementa un sotto-insieme della sintassi del PHP, eliminando le forme obsolete (ancora presenti nel PHP per ragioni di compatibilità all'indietro) ed eliminando le forme pericolose e di cattiva pratica di programmazione.

Still no comments to this page. Use the Comments link above to add your contribute.