M2 - Report

www.icosaedro.it

M2 Report

Frontespizio
Introduzione
Caratteristiche
Un semplice esempio
Moduli
Sezione IMPORT
Sezione CONST
Sezione TYPE
Tipo FORWARD
Sezione VAR
Sezione FUNCTION
Sezione BEGIN
Stringhe letterali
Sottostringhe
Commenti
Costanti predefinite
Variabili predefinite
Funzioni predefinite
Istruzione di assegnamento
Istruzione per la chiamata di funzione
Ordine di valutazione degli argomenti attuali
Istruzione IF
Istruzione SWITCH
Istruzione FOR
Istruzione WHILE
Istruzione REPEAT
Istruzione LOOP
Istruzione TRY
Istruzione RAISE ERROR
Istruzione RETURN
Espressioni logiche
Espressioni intere
Espressioni reali
Espressioni stringa
Espressioni tra tipi strutturati
Regole di scope
M2 per programmatori C
M2 per programmatori Java
Rappresentazione dei dati in memoria
Keywords
Messaggi di errore a runtime
Sintassi

Sintassi

Il formalismo BNF permette di descrivere sinteticamente la sintassi del linguaggio M2. Il sorgente del programma deve corrispondere ad una compilation_unit. Il rispetto delle clausole sintattiche è condizione necessaria ma non sufficiente perché la compilazione si concluda correttamente. Vari aspetti della sintassi e della semantica del linguaggio sono discussi nel testo.

Tra due elementi sintattici si possono inserire un numero arbitrario di spazi, caratteri di tabulazione, a-capo e commenti. Questi caratteri vengono ignorati dal compilatore e non contribuiscono al codice prodotto. Fanno eccezione le stringhe letterali (string), i numeri (number) e i nomi qualificati (qualified_name): questi elementi sintattici non possono essere interrotti da spaziature o altri caratteri.

Tutte le dichiarazioni BNF sono numerate, e i numeri a pedice degli identificatori permettono di trovare rapidamente la corrispondente dichiarazione.

1. compilation_unit = definition_module₂ | implementation_module₃ | module₄ ;
2. definition_module = "DEFINITION" "MODULE" module_name₅ import₆ { const_decl₇ | var_decl₁₁ | function_decl₂₃ } "END" ;
3. implementation_module = "IMPLEMENTATION" "MODULE" module_name₅ import₆ { const_decl₇ | type_decl₁₀ | var_decl₁₁ | function_decl₂₃ function_body₂₅ } "END" ;
4. module = "MODULE" module_name₅ import₆ function_body₂₅ ;
5. module_name = name₆₈ ;
6. import = { "IMPORT" [ module_name₅ { "," module_name₅ } ] } ;
7. const_decl = "CONST" { name₆₈ "=" const_value₈ } ;
8. const_value = boolean₄₈ | [ "+" | "-" ] number₄₉ | [ "+" | "-" ] const_name₉ | string₆₀ ;
9. const_name = qualified_name₇₀ ;
10. type_decl = "TYPE" { name₆₈ "=" ( "FORWARD" | type₁₂ ) } ;
11. var_decl = "VAR" [ "STATIC" ] { name₆₈ { "," name₆₈ } ":" type₁₂ } ;
12. type = simple_type₁₄ | array_type₁₈ | record_type₁₉ | function_type₂₂ | type_name₁₃ ;
13. type_name = qualified_name₇₀ ;
14. simple_type = "VOID" | "BOOLEAN" | "INTEGER" | enum_type₁₅ | "REAL" | "STRING" ;
15. enum_type = "(" enum_elem₁₆ { "," enum_elem₁₆ } ")" ;
16. enum_elem = name₆₈ [ "=" const_integer₁₇ ] ;
17. const_integer = int_number₅₂ | const_name₉ ;
18. array_type = "ARRAY" "OF" type₁₂ ;
19. record_type = "RECORD" { field_decl₂₀ } "END" ;
20. field_decl = field_name₂₁ { "," field_name₂₁ } ":" type₁₂ ;
21. field_name = name₆₈ ;
22. function_type = function_decl₂₃ ;
23. function_decl = "FUNCTION" name₆₈ "(" [ formal_arg₂₄ { "," formal_arg₂₄ } ] ")" [ ":" type₁₂ ] [ "RAISE" "ERROR" ] ;
24. formal_arg = [ "VAR" ] name₆₈ ":" type₁₂ ;
25. function_body = { const_decl₇ | type_decl₁₀ | var_decl₁₁ | function_decl₂₃ function_body₂₅ } "BEGIN" { instruction₂₆ } "END" ;
26. instruction = assignment₂₇ | function_call₂₈ | if₃₃ | switch₃₄ | while₃₅ | repeat₃₆ | for₃₇ | loop₃₈ | exit₃₉ | try₄₀ | raise₄₁ | return₄₂ ;
27. assignment = var_name₆₄ { selector₆₅ } "=" expr₄₃ ;
28. function_call = prefix_function_call₂₉ | postfix_function_call₃₀ ;
29. prefix_function_call = function_name₃₁ "(" { actual_arg₃₂ } ")" ;
30. postfix_function_call = ( var_name₆₄ | function_name₃₁ "(" { actual_arg₃₂ } ")" ) { "->" qualified_name₇₀ "(" { actual_arg₃₂ } ")" } ;
31. function_name = qualified_name₇₀ ;
32. actual_arg = expr₄₃ | var_name₆₄ { selector₆₅ } ;
33. if = "IF" expr₄₃ "THEN" { instruction₂₆ } { "ELSIF" expr₄₃ "THEN" { instruction₂₆ } } [ "ELSE" { instruction₂₆ } ] "END" ;
34. switch = "SWITCH" expr₄₃ "DO" { "CASE" const_integer₁₇ { "," const_integer₁₇ } ":" { instruction₂₆ } } [ "ELSE" { instruction₂₆ } ] "END" ;
35. while = "WHILE" expr₄₃ "DO" { instruction₂₆ } "END" ;
36. repeat = "REPEAT" { instruction₂₆ } "UNTIL" expr₄₃ ;
37. for = "FOR" qualified_name₇₀ "=" expr₄₃ "TO" expr₄₃ [ "BY" const_integer₁₇ ] "DO" { instruction₂₆ } "END" ;
38. loop = "LOOP" { instruction₂₆ } "END" ;
39. exit = "EXIT" ;
40. try = "TRY" ( assignment₂₇ | function_call₂₈ ) { "CATCH" const_integer₁₇ { "," const_integer₁₇ } ":" { instruction₂₆ } } [ "ELSE" { instruction₂₆ } ] "END" ;
41. raise = "RAISE" "ERROR" expr₄₃ expr₄₃ ;
42. return = "RETURN" [ expr₄₃ ] ;
43. expr = simple_expr₄₄ [ relation₄₇ simple_expr₄₄ ] ;
44. simple_expr = [ "+" | "-" ] term₄₅ { add_operator₅₀ term₄₅ } ;
45. term = factor₄₆ { mult_operator₅₁ factor₄₆ } ;
46. factor = "NIL" | boolean₄₈ | number₄₉ | string₆₀ | const_name₉ | var_name₆₄ { selector₆₅ } [ substr_selector₆₃ ] | function_call₂₈ | "(" expr₄₃ ")" | "NOT" factor₄₆ | "~" factor₄₆ ;
47. relation = "<" | "<=" | "=" | ">=" | ">" | "<>" ;
48. boolean = "FALSE" | "TRUE" ;
49. number = int_number₅₂ | real_number₅₇ ;
50. add_operator = "+" | "-" | "OR" | "^" | "|" ;
51. mult_operator = "*" | "/" | "DIV" | "MOD" | "AND" | "&" ;
52. int_number = integer₅₃ | hex_integer₅₅ ;
53. integer = digit₅₄ { digit₅₄ } ;
54. digit = "0".."9" ;
55. hex_integer = "0x" hex_digit₅₆ { hex_digit₅₆ } ;
56. hex_digit = digit₅₄ | "a".."f" | "A".."F" ;
57. real_number = integer₅₃ ( decimals₅₈ [ exponent₅₉ ] | [ decimals₅₈ ] exponent₅₉ ) ;
58. decimals = "." integer₅₃ ;
59. exponent = ( "e" | "E" ) [ "+" | "-" ] integer₅₃ ;
60. string = "\"" { str_char₆₁ | str_escape₆₂ } "\"" ;
61. str_char = " " | "!" | "#".."[" | "]".."~" ;
62. str_escape = "\\" ( "\\" | "\"" | "a" | "b" | "n" | "r" | "t" | "x" hex_digit₅₆ hex_digit₅₆ ) ;
63. substr_selector = "[" expr₄₃ [ "," expr₄₃ ] "]" ;
64. var_name = qualified_name₇₀ ;
65. selector = "[" ( index₆₇ | field_name₂₁ ) "]" | next_elem_in_array₆₆ ;
66. next_elem_in_array = "[" "]" ;
67. index = expr₄₃ ;
68. name = ( letter₆₉ | "_" ) { letter₆₉ | digit₅₄ | "_" } ;
69. letter = "a".."z" | "A".."Z" ;
70. qualified_name = [ module_name₅ "." ] name₆₈ ;

<= Messaggi di errore a runtime

Umberto Salsi

Contatto

Mappa

Home / Indice sezione